Notification Area Icons
When you start a computer that is running Windows Vista or Windows 7 one or more of your icons do not appear in the notification area in the lower-right corner of the screen. Also, the Volume Control icon, the Network icon and the Power icon may be missing. I have two Windows 7 systems and this is only happening on the 32-bit machine. But it happens reliably on reboot so I have to do this regularly.
You can make them reappear by deleting two subkeys from the registry.
The next time this happens you can simply double-click the .reg file you just saved, allow it to modify the registry, and do steps 5-7 above. Fixing the problem this way means you don't have to re-set the Notification Area Customizations every time you have to do this.
Alternatively, you can use the batch file below. Highlight from rem begin batch file to rem end batch file. Press CTRL+C to copy the text to the clipboard. Open a plain text editor like Notepad. Press CTRL+V to paste the text. Save the file as Reset Notification Icons.bat. The next time this happens run this batch file. It deletes the proper registry keys, kills the explorer.exe processes, and then restarts explorer.exe.
You can also just download the batch file here.
rem begin batch file
:: Created by: Shawn Brink
:: http://www.sevenforums.com
:: Tutorial: http://www.sevenforums.com/tutorials/13102-notification-area-icons-reset.html
rem Modified by Ed Mullen, February 2013
@echo off
cls
set regPath=HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify
set regKey1=IconStreams
set regKey2=PastIconsStream
echo The Explorer process must be killed to reset the Notification Area Icons Cache.
echo.
echo Please SAVE ALL OPEN WORK before continuing
echo.
pause
echo.
taskkill /IM explorer.exe /F
echo.
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey1% ^| find /i "%regkey1%"') do goto iconstreams
echo Registry key "IconStreams" already deleted.
echo.
:verify-PastIconsStream
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey2% ^| find /i "%regkey2%"') do goto PastIconsStream
echo Registry key "PastIconsStream" already deleted.
echo.
goto confirm-restart
:iconstreams
reg delete "%regpath%" /f /v "%regkey1%"
goto verify-PastIconsStream
:PastIconsStream
reg delete "%regpath%" /f /v "%regkey2%"
:confirm-restart
echo.
echo.
echo We must restart explorer.exe.
echo.
:wrong
set /p choice=Restart explorer.exe now? (Y/N) and press Enter:
If %choice% == y goto Yes
If %choice% == Y goto Yes
If %choice% == n goto No
If %choice% == N goto No
goto wrong
:Yes
start explorer.exe
exit
:No
echo.
echo Restart aborted. You need to restart explorer.exe manually.
wait 3
exit
rem end batch file
This page last changed: Friday, July 24, 2015 - 01:51 PM USA Eastern Time
Copyright Ed Mullen | Contact Ed